Процедура Write – записує дані до бінарного або текстового файлу

Процедура Write в Delphi записує дані до бінарного або текстового файлу.

Процедура Write: Ілюстрація запису простого, множинного та форматованого рядка тексту

var
  myFile : TextFile;
  text   : string;
  i      : Integer;

begin
  // Спроба відкрити файл Test.txt для запису
  AssignFile(myFile, 'Test.txt');
  ReWrite(myFile);

  // Запис кількох відомих слів у цей файл
  Write(myFile, 'Hello ');
  Write(myFile, 'World');

  // Закінчуємо цей рядок
  WriteLn(myFile);

  // Записуємо деякі числа у файл як одиночну лінію
  for i := 2 to 4 do
    Write(myFile, i/2, '  ');

  // Закінчуємо цей рядок
  WriteLn(myFile);

  // Повторення вищезгаданого, але з форматуванням чисел
  for i := 2 to 4 do
    Write(myFile, i/2:5:1);

  // Закінчуємо цей рядок
  WriteLn(myFile);

  // Закриваємо файл
  CloseFile(myFile);

  // Повторне відкриття файлу лише для читання
  Reset(myFile);

  // Показ вмісту файлу
  while not Eof(myFile) do
  begin
    ReadLn(myFile, text);
    ShowMessage(text);
  end;

  // Закриття файлу востаннє
  CloseFile(myFile);
end;

Процедура Write: Запис типізованих записів у двійковий файл типу запису

type
  TCustomer = record
    name : string[20];
    age  : Integer;
    male : Boolean;
  end;

var
  myFile   : File of TCustomer;  // Файл запису клієнта
  customer : TCustomer;

begin
  // Спроба відкрити бінарний файл Test.cus для запису
  AssignFile(myFile, 'Test.cus');
  ReWrite(myFile);

  // Запис кількох записів клієнта у файл
  customer.name := 'Fred Bloggs';
  customer.age  := 21;
  customer.male := true;
  Write(myFile, customer);

  customer.name := 'Jane Turner';
  customer.age  := 45;
  customer.male := false;
  Write(myFile, customer);

  // Закриття файлу
  CloseFile(myFile);

  // Повторне відкриття файлу лише для читання
  FileMode := fmOpenRead;
  Reset(myFile);

  // Показ вмісту файлу
  while not Eof(myFile) do
  begin
    Read(myFile, customer);
    if customer.male
    then ShowMessage("Чоловік на ім'я "+customer.name+
                     " - "+IntToStr(customer.age))
    else ShowMessage("Жінка на ім'я "+customer.name+
                     " - "+IntToStr(customer.age));
  end;

  // Закриття файлу востаннє
  CloseFile(myFile);
end;

Процедура Write: Запис у двійковий файл типу Word

var
  myWord, myWord1, myWord2 : Word;
  myFile : File of Word;

begin
  // Спроба відкрити бінарний файл Test.bin для запису
  AssignFile(myFile, 'Test.bin');
  ReWrite(myFile);

  // Запис кількох рядків Word даних у файл
  myWord1 := 234;
  myWord2 := 567;
  Write(myFile, myWord1, myWord2);

  // Закриття файлу
  CloseFile(myFile);

  // Повторне відкриття файлу лише для читання
  FileMode := fmOpenRead;
  Reset(myFile);

  // Показ вмісту файлу
  while not Eof(myFile) do
  begin
    Read(myFile, myWord);
    ShowMessage(IntToStr(myWord));
  end;

  // Закриття файлу востаннє
  CloseFile(myFile);
end;